
public skill_death_sting_reset(parm[2])
{
	static id,victim;
	id=parm[0];
	victim=parm[1];
	
	if(is_user_alive(victim))
	{
		print_hud_status(id,"%L",id,"L_STATUS_SKILL_DS_DISSAPPEAR");
		print_hud_status(victim,"%L",victim,"L_STATUS_SKILL_DS_DISSAPPEAR_TARGET");
		g_player_death_stinged[victim] = 0;
		remove_status_icon(victim);
	}
}

public skill_death_sting(id,victim,weapon,hitplace)
{
	if(!weapon || weapon == CSW_KNIFE || weapon == CSW_C4)
	{
		return PLUGIN_CONTINUE;
	}
	
	if(g_player_death_stinged[victim] == 0)
	{
		static random_hit;
		random_hit = random_num(HIT_HEAD,HIT_RIGHTLEG);
		if(random_hit < hitplace)
		{
			g_player_death_stinged[victim]=hitplace;
			print_hud_status(victim,"%L",victim,"L_STATUS_SKILL_DS_BODY");
			
			remove_status_icon(victim);
			g_player_statusicon[victim]="dmg_bio";
			create_status_icon(victim,2,g_player_statusicon[victim],255,255,255);
			
			static task,parm[2];
			
			task = BLEACH_TASK_STING + id;
			remove_task(task,0);
			
			parm[0] = id;
			parm[1] = victim;
			
			set_task(2.0*g_skill[id][P_SKILL_6],"skill_death_sting_reset",task,parm,2);
		}
	}
	else if(g_player_death_stinged[victim] == hitplace)
	{
		g_player_died_by_skill[victim]=true;
		print_hud_status(id,"%L",id,"L_STATUS_SKILL_DS_KILL");
		
		set_msg_block(g_msg_death_msg,BLOCK_ONCE);
		user_kill(victim,1);
		skill_deathmsg(id,victim);
	}
	
	return PLUGIN_CONTINUE;
}
